CFPRIME INE30                                                           INE30       1
C***********************************************************************RIGHTE      1
C*                                                                     *RIGHTE      2
C*        Extended Transient-Midterm Stability Program (ETMSP)         *RIGHTE      3
C*        ====================================================         *RIGHTE      4
C*                                                                     *RIGHTE      5
C*       Copyright (C) (1993) Electric Power Research Institute        *RIGHTE      6
C*                                                                     *RIGHTE      7
C* EPRI reserves all rights in the software and associated             *RIGHTE      8
C* documentation as delivered. The software and its associated         *RIGHTE      9
C* documention or any portion thereof may not be reproduced in any form*RIGHTE     10
C* whatsoever without the consent of EPRI, except as explicity provided*RIGHTE     11
C* for by license. Licensee shall submit a detailed description to EPRI*RIGHTE     12
C* of any changes or modifications to the software within two (2)      *RIGHTE     13
C* months after such changes or modifications are made. At EPRI's sole *RIGHTE     14
C* discretion, the software, as changed or modified, shall be given a  *RIGHTE     15
C* new designation sufficiently different from its then current        *RIGHTE     16
C* designation as to prevent mistake,confusion, or deception as between*RIGHTE     17
C* the current software as changed or modified.                        *RIGHTE     18
C*                                                                     *RIGHTE     19
C* A license under EPRI's rights in the software can be obtained       *RIGHTE     20
C* directly from EPRI.                                                 *RIGHTE     21
C*                                                                     *RIGHTE     22
C* This program and supporting materials may be independently available*RIGHTE     23
C* from Electric Power Software centre (EPSC) for an appropriate       *RIGHTE     24
C* distribution fee. The EPSC is a service of                          *RIGHTE     25
C*                                                                     *RIGHTE     26
C*                    Power Computing Company                          *RIGHTE     27
C*                    1930 Hi Line                                     *RIGHTE     28
C*                    Dallas, Tx 75207                                 *RIGHTE     29
C*                                                                     *RIGHTE     30
C* NEITHER EPRI, ANY MEMBER OF EPRI, NOR ANY PERSON OR  ORGANIZATION   *RIGHTE     31
C* ACTING ON BEHAVE OF THEM:                                           *RIGHTE     32
C*                                                                     *RIGHTE     33
C* 1. MAKE ANY WARRANTY OR REPRESENTATION WHATSOEVER, EXPRESS OR       *RIGHTE     34
C*    IMPLIED, INCLUDING ANY WARRANTY OF MERCHANTABILITY OR FITNESS OR *RIGHTE     35
C*    ANY PURPOSE WITH RESPECT TO THE SOFTWARE OR ITS ASSOCIATED       *RIGHTE     36
C*    DOCUMENTATION; OR                                                *RIGHTE     37
C*                                                                     *RIGHTE     38
C* 2. ASSUMES ANY LIABILITY WHATSOEVER WITH RESPECT TO ANY USE OF THE  *RIGHTE     39
C*    SOFTWARE OR ITS ASSOCIATED DOCUMENTATION OR ANY PORTION THEREOF  *RIGHTE     40
C*    OR WITH RESPECT TO ANY DAMAGES WHICH MAY RESULT FROM SUCH USE.   *RIGHTE     41
C*                                                                     *RIGHTE     42
C* THIS NOTICE MAY NOT BE REMOVED FROM THE SOFTWARE BY ANY USER        *RIGHTE     43
C* THEREOF.                                                            *RIGHTE     44
C*                                                                     *RIGHTE     45
C***********************************************************************RIGHTE     46
      SUBROUTINE INE30                                                  INE30       3
CD                                                                      INE30       4
CD    TO PERFORM INITIALIZATION AND DATA CHECK FOR EXCITER TYPE 30.     INE30       5
CD                                                                      INE30       6
CD    THE DATA STRUCTURE AFTER THE INITIALIZATION IS GIVEN BELOW.       INE30       7
CD                                                                      INE30       8
CD   3.12 Exciter type 30                                               INE30       9
CD                                                                      INE30      10
CD     Exciter data                                                     INE30      11
CD                                                                      INE30      12
CD     IDDAT(JE+ 1)   = IVTN         : sensing bus number               INE30      13
CD     DDAT(JE+ 2)    = KA                                              INE30      14
CD     DDAT(JE+ 3)    = TA                                              INE30      15
CD     DDAT(JE+ 4)    = TC                                              INE30      16
CD     DDAT(JE+ 5)    = TB                                              INE30      17
CD     DDAT(JE+ 6)    = KF                                              INE30      18
CD     DDAT(JE+ 7)    = TF                                              INE30      19
CD     DDAT(JE+ 8)    = TF1                                             INE30      20
CD     DDAT(JE+ 9)    = TF2                                             INE30      21
CD     DDAT(JE+10)    = VRMAX                                           INE30      22
CD     DDAT(JE+11)    = VRMIN                                           INE30      23
CD     DDAT(JE+12)    = ETV                                             INE30      24
CD     DDAT(JE+13)    = KVF                                             INE30      25
CD     DDAT(JE+14)    = ETMIN                                           INE30      26
CD     DDAT(JE+15)    = KIFL                                            INE30      27
CD     DDAT(JE+16)    = IFLMT                                           INE30      28
CD     DDAT(JE+17)    = (reserved for future use)                       INE30      29
CD     DDAT(JE+18)    = TR                                              INE30      30
CD     DDAT(JE+19)    = RC                                              INE30      31
CD     DDAT(JE+20)    = XC                                              INE30      32
CD     DDAT(JE+21)    = KETL                                            INE30      33
CD     DDAT(JE+22)    = TL1                                             INE30      34
CD     DDAT(JE+23)    = TL2                                             INE30      35
CD     DDAT(JE+24)    = ETLMT                                           INE30      36
CD     DDAT(JE+25)    = VOMX                                            INE30      37
CD     DDAT(JE+26)    = VSMAX                                           INE30      38
CD     DDAT(JE+27)    = VSMIN                                           INE30      39
CD     DDAT(JE+28)    = VIMAX                                           INE30      40
CD     DDAT(JE+29)    = VIMIN                                           INE30      41
CD                                                                      INE30      42
CD     Exciter states                                                   INE30      43
CD                                                                      INE30      44
CD     XSTATE(JES+1)  = TR block     : compulsory                       INE30      45
CD     XSTATE(JES+2)  = TL2 block    : optional                         INE30      46
CD     XSTATE(JES+3)  = TF2 block    : optional                         INE30      47
CD     XSTATE(JES+4)  = TF block     : optional                         INE30      48
CD     XSTATE(JES+5)  = TB block     : optional                         INE30      49
CD     XSTATE(JES+6)  = TA block     : compulsory                       INE30      50
CD                                                                      INE30      51
CD     Exciter Y-variables                                              INE30      52
CD                                                                      INE30      53
CD     VREG(JYE+1)    = VC (input to the TR block)                      INE30      54
CD     VREF(JYE+2)    = reference value                                 INE30      55
CD     VRFIN(JYE+3)   = output of TA block (exciter EFD)                INE30      56
CD                                                                      INE30      57
      INCLUDE 'PARX.INS'                                                INE30      58
      INCLUDE 'CNMDAT.INS'                                              INE30      59
      INCLUDE 'CNMSTA.INS'                                              INE30      60
      INCLUDE 'CNXSTA.INS'                                              INE30      61
      INCLUDE 'CNB8.INS'                                                INE30      62
      INCLUDE 'CNEXC.INS'                                               INE30      63
      INCLUDE 'CNMYVA.INS'                                              INE30      64
      INCLUDE 'CNUNIT.INS'                                              INE30      65
      INCLUDE 'CNYVAR.INS'                                              INE30      66
      INCLUDE 'CNSTN.INS'                                               INE30      67
      INCLUDE 'CNB1.INS'                                                INE30      68
      INCLUDE 'CNB4.INS'                                                INE30      69
      INCLUDE 'CNIMPR.INS'                                              INE30      70
      INCLUDE 'CNMSG.INS'                                               INE30      71
      INCLUDE 'CNXDOT.INS'                                              INE30      72
C                                                                       INE30      73
      DATA BIG/99.9/                                                    INE30      74
C                                                                       INE30      75
C     INPUT TIME CONSTANTS CHECK AND RESET                              INE30      76
C                                                                       INE30      77
      IF(DDAT(JE+3).LT.TMIN.AND.IDDAT(JE+3).NE.0)THEN                   INE30      78
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30      79
     *                     ,NDGC(N)                                     INE30      80
         WRITE(MSG(2),9010)                                             INE30      81
         IF(MTFLAG.EQ.0) THEN                                           INE30      82
            WRITE(MSG(3),9030) 'TA',DDAT(JE+3),TMIN                     INE30      83
         ELSE                                                           INE30      84
            WRITE(MSG(3),9030) 'TA',DDAT(JE+3),TMIN,'TA',TMIN           INE30      85
            DDAT(JE+3)=TMIN                                             INE30      86
         ENDIF                                                          INE30      87
         CALL PRTMSG(3)                                                 INE30      88
      ENDIF                                                             INE30      89
C                                                                       INE30      90
      IF (IDDAT(JE+6).EQ.0) THEN                                        INE30      91
         DDAT(JE+7)=0.0                                                 INE30      92
      ELSE IF (DDAT(JE+7).EQ.0) THEN                                    INE30      93
         DDAT(JE+6)=0.0                                                 INE30      94
      END IF                                                            INE30      95
      IF (DDAT(JE+7).LT.TMIN.AND.IDDAT(JE+7).NE.0) THEN                 INE30      96
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30      97
     *                     ,NDGC(N)                                     INE30      98
         WRITE(MSG(2),9010)                                             INE30      99
         IF(MTFLAG.EQ.0) THEN                                           INE30     100
            WRITE(MSG(3),9030) 'TF',DDAT(JE+7),TMIN                     INE30     101
         ELSE                                                           INE30     102
            WRITE(MSG(3),9030) 'TF',DDAT(JE+7),TMIN,'TF',TMIN           INE30     103
            DDAT(JE+7)=TMIN                                             INE30     104
         ENDIF                                                          INE30     105
         CALL PRTMSG(3)                                                 INE30     106
      END IF                                                            INE30     107
C                                                                       INE30     108
      IF (DDAT(JE+5).LT.TMIN.AND.IDDAT(JE+5).NE.0) THEN                 INE30     109
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30     110
     *                     ,NDGC(N)                                     INE30     111
         WRITE(MSG(2),9010)                                             INE30     112
         IF(MTFLAG.EQ.0) THEN                                           INE30     113
            WRITE(MSG(3),9030) 'TB',DDAT(JE+5),TMIN                     INE30     114
         ELSEIF(IDDAT(JE+3).EQ.0.AND.IDDAT(JE+7).NE.0) THEN             INE30     115
            WRITE(MSG(3),9030) 'TB',DDAT(JE+5),TMIN,'TB',TMIN           INE30     116
            DDAT(JE+5)=TMIN                                             INE30     117
         ELSE                                                           INE30     118
            WRITE(MSG(3),9030) 'TB',DDAT(JE+5),TMIN,'TB',0.0            INE30     119
            DDAT(JE+5)=0.0                                              INE30     120
         ENDIF                                                          INE30     121
         CALL PRTMSG(3)                                                 INE30     122
      ELSE IF (IDDAT(JE+5).EQ.0.AND.IDDAT(JE+3).EQ.0.AND.               INE30     123
     *         IDDAT(JE+7).NE.0) THEN                                   INE30     124
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30     125
     *                     ,NDGC(N)                                     INE30     126
         WRITE(MSG(2),9010)                                             INE30     127
         WRITE(MSG(3),9050)                                             INE30     128
         IF(MTFLAG.EQ.0) THEN                                           INE30     129
            CALL PRTMSG(3)                                              INE30     130
         ELSE                                                           INE30     131
         WRITE(MSG(4),9060) TMIN                                        INE30     132
         CALL PRTMSG(4)                                                 INE30     133
         DDAT(JE+5)=TMIN                                                INE30     134
         ENDIF                                                          INE30     135
      ENDIF                                                             INE30     136
C                                                                       INE30     137
      IF(DDAT(JE+9).LT.TMIN.AND.IDDAT(JE+9).NE.0)THEN                   INE30     138
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30     139
     *                     ,NDGC(N)                                     INE30     140
         WRITE(MSG(2),9010)                                             INE30     141
         IF(MTFLAG.EQ.0) THEN                                           INE30     142
            WRITE(MSG(3),9030) 'TF2',DDAT(JE+9),TMIN                    INE30     143
         ELSE                                                           INE30     144
            WRITE(MSG(3),9030) 'TF2',DDAT(JE+9),TMIN,'TF2',0.0          INE30     145
            DDAT(JE+9)=0.0                                              INE30     146
         ENDIF                                                          INE30     147
         CALL PRTMSG(3)                                                 INE30     148
      ENDIF                                                             INE30     149
C                                                                       INE30     150
      IF(DDAT(JE+18).LT.TMIN.AND.IDDAT(JE+18).NE.0)THEN                 INE30     151
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30     152
     *                     ,NDGC(N)                                     INE30     153
         WRITE(MSG(2),9010)                                             INE30     154
         IF(MTFLAG.EQ.0) THEN                                           INE30     155
            WRITE(MSG(3),9030) 'TR',DDAT(JE+18),TMIN                    INE30     156
         ELSE                                                           INE30     157
            WRITE(MSG(3),9030) 'TR',DDAT(JE+18),TMIN,'TR',0.0           INE30     158
            DDAT(JE+18)=0.0                                             INE30     159
         ENDIF                                                          INE30     160
         CALL PRTMSG(3)                                                 INE30     161
      ENDIF                                                             INE30     162
C                                                                       INE30     163
      IF(DDAT(JE+23).LT.TMIN.AND.IDDAT(JE+23).NE.0)THEN                 INE30     164
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30     165
     *                     ,NDGC(N)                                     INE30     166
         WRITE(MSG(2),9010)                                             INE30     167
         IF(MTFLAG.EQ.0) THEN                                           INE30     168
            WRITE(MSG(3),9030) 'TL2',DDAT(JE+23),TMIN                   INE30     169
         ELSE                                                           INE30     170
            WRITE(MSG(3),9030) 'TL2',DDAT(JE+23),TMIN,'TL2',0.0         INE30     171
            DDAT(JE+23)=0.0                                             INE30     172
         ENDIF                                                          INE30     173
         CALL PRTMSG(3)                                                 INE30     174
      ENDIF                                                             INE30     175
C                                                                       INE30     176
      IF (IDDAT(JE+25).EQ.0) DDAT(JE+25)=BIG                            INE30     177
      IF (IDDAT(JE+28).EQ.0.AND.IDDAT(JE+29).EQ.0) THEN                 INE30     178
         DDAT(JE+28)=BIG                                                INE30     179
         DDAT(JE+29)=-BIG                                               INE30     180
      ENDIF                                                             INE30     181
      IF (IDDAT(JE+10).EQ.0.AND.IDDAT(JE+11).EQ.0) THEN                 INE30     182
         DDAT(JE+10)=BIG                                                INE30     183
         DDAT(JE+11)=-BIG                                               INE30     184
      ENDIF                                                             INE30     185
      IF (IDDAT(JE+26).EQ.0.AND.IDDAT(JE+27).EQ.0) THEN                 INE30     186
         DDAT(JE+26)=DDAT(JE+28)                                        INE30     187
         DDAT(JE+27)=DDAT(JE+29)                                        INE30     188
      ENDIF                                                             INE30     189
C                                                                       INE30     190
C  SET UP THE FLAG FOR SUBINTERVAL INTEGRATION :                        INE30     191
C        IDDAT(JE+31)=1 -- SUBINTERVAL INTEGRATION MODE                 INE30     192
C        IDDAT(JE+31)=0 -- NORMAL RKG MODE                              INE30     193
C                                                                       INE30     194
      IF (IDDAT(JE+6).EQ.0.OR.IDDAT(JE+7).EQ.0) THEN                    INE30     195
         DDAT(JE+8)=0.0                                                 INE30     196
         DDAT(JE+9)=0.0                                                 INE30     197
         IDDAT(JE+31)=0                                                 INE30     198
      ELSE                                                              INE30     199
         IDDAT(JE+31)=1                                                 INE30     200
      ENDIF                                                             INE30     201
C                                                                       INE30     202
C     DDAT(JE+34) THROUGH DDAT(JE+38) ARE USED TO STORE THE             INE30     203
C     SUBSCRIPTS OF OPTIONAL BLOCKS. IF ZERO, THE CORRESPONDING         INE30     204
C     BLOCK IS NOT PRESENT.                                             INE30     205
C                                                                       INE30     206
      IDDAT(JE+34)=0                                                    INE30     207
      IDDAT(JE+35)=0                                                    INE30     208
      IDDAT(JE+36)=0                                                    INE30     209
      IDDAT(JE+37)=0                                                    INE30     210
      IDDAT(JE+38)=0                                                    INE30     211
      DDAT(JE+39)=XSTATE(JSTATE+1)                                      INE30     212
C                                                                       INE30     213
      KSTATE=1                                                          INE30     214
      VE=EFDN/DDAT(JE+2)                                                INE30     215
C                                                                       INE30     216
C  EXCITER CELING REGULATOR                                             INE30     217
C                                                                       INE30     218
      IF (IDDAT(JE+12).NE.0)THEN                                        INE30     219
      ETR=ET/DDAT(JE+12)                                                INE30     220
      ELSE                                                              INE30     221
      ETR=1.0                                                           INE30     222
      ENDIF                                                             INE30     223
C                                                                       INE30     224
      EFCF=DDAT(JE+13)*EFDN                                             INE30     225
      EFMX=DDAT(JE+10)*ETR-EFCF                                         INE30     226
      EFMN=DDAT(JE+11)*ETR+EFCF                                         INE30     227
C                                                                       INE30     228
C  TERMINAL VOLTAGE LIMITER BLOCK                                       INE30     229
C                                                                       INE30     230
      IF (IDDAT(JE+21).EQ.0) THEN                                       INE30     231
         DDAT(JE+21)=0.0                                                INE30     232
         DDAT(JE+22)=0.0                                                INE30     233
         DDAT(JE+23)=0.0                                                INE30     234
         DDAT(JE+24)=99.0                                               INE30     235
      END IF                                                            INE30     236
C                                                                       INE30     237
      IF (IDDAT(JE+21).NE.0) THEN                                       INE30     238
      IF(ET.GT.DDAT(JE+24))THEN                                         INE30     239
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30     240
     *                     ,NDGC(N)                                     INE30     241
         WRITE(MSG(2),9010)                                             INE30     242
         WRITE(MSG(3),9020) ET,DDAT(JE+24)                              INE30     243
         CALL PRTMSG(3)                                                 INE30     244
      ENDIF                                                             INE30     245
C                                                                       INE30     246
C  V2 PRIME - OPTIONAL                                                  INE30     247
C                                                                       INE30     248
      IF(IDDAT(JE+23).NE.0)THEN                                         INE30     249
         KSTATE=KSTATE+1                                                INE30     250
         XSTATE(JSTATE+KSTATE)=0.                                       INE30     251
         IDDAT(JE+34)=JSTATE+KSTATE-NSTATE                              INE30     252
      ENDIF                                                             INE30     253
C                                                                       INE30     254
      ENDIF                                                             INE30     255
C                                                                       INE30     256
C  V5 PRIME -- OPTIONAL                                                 INE30     257
C                                                                       INE30     258
       IF (IDDAT(JE+7).NE.0.AND.IDDAT(JE+6).NE.0)THEN                   INE30     259
          KSTATE=KSTATE+1                                               INE30     260
          XSTATE(JSTATE+KSTATE)=EFDN                                    INE30     261
          IDDAT(JE+35)=JSTATE+KSTATE-NSTATE                             INE30     262
C                                                                       INE30     263
C  V5 PRIME PRIME -- OPTIONAL                                           INE30     264
C                                                                       INE30     265
          IF (IDDAT(JE+9).NE.0)THEN                                     INE30     266
             KSTATE=KSTATE+1                                            INE30     267
             XSTATE(JSTATE+KSTATE)=0.0                                  INE30     268
             IDDAT(JE+36)=JSTATE+KSTATE-NSTATE                          INE30     269
          ENDIF                                                         INE30     270
       ENDIF                                                            INE30     271
C                                                                       INE30     272
C  V3 PRIME -- OPTIONAL                                                 INE30     273
C                                                                       INE30     274
       IF (IDDAT(JE+5).NE.0)THEN                                        INE30     275
       KSTATE=KSTATE+1                                                  INE30     276
       XSTATE(JSTATE+KSTATE)=VE                                         INE30     277
       IDDAT(JE+37)=JSTATE+KSTATE-NSTATE                                INE30     278
       ENDIF                                                            INE30     279
C                                                                       INE30     280
C  V4                                                                   INE30     281
C                                                                       INE30     282
       KSTATE=KSTATE+1                                                  INE30     283
       XSTATE(JSTATE+KSTATE)=EFDN                                       INE30     284
C                                                                       INE30     285
       XDFACT(JSTATE+KSTATE)=DDAT(JE+2)                                 INE30     286
C                                                                       INE30     287
       VREF(JYE+2)=XSTATE(JSTATE+1)+EFDN/DDAT(JE+2)                     INE30     288
       IDDAT(JE+38)=JSTATE+KSTATE-NSTATE                                INE30     289
C                                                                       INE30     290
C      IF TA NON-ZERO, IDDAT(JE+33) = 1                                 INE30     291
C      IF TA = 0.0, IDDAT(JE+33) = 2                                    INE30     292
C                                                                       INE30     293
C      THIS FLAG IS USED IN IMPLICIT METHOD.                            INE30     294
C                                                                       INE30     295
       IF (IDDAT(JE+3).EQ.0) THEN                                       INE30     296
          IDDAT(JE+33)=2                                                INE30     297
       ELSE                                                             INE30     298
          IDDAT(JE+33)=1                                                INE30     299
       END IF                                                           INE30     300
C                                                                       INE30     301
      VRFIN(JYE+3)=EFDN                                                 INE30     302
      JSTATE=JSTATE+KSTATE                                              INE30     303
      JY=JY+3                                                           INE30     304
C                                                                       INE30     305
C  DETERMINE THE LARGEST TIME STEP PERMITTED                            INE30     306
C                                                                       INE30     307
      IDDAT(JE+41)=KSTATE                                               INE30     308
      TMAX=99.0                                                         INE30     309
      IF (IDDAT(JE+6).NE.0.AND.IDDAT(JE+7).NE.0) THEN                   INE30     310
         TMAX=DDAT(JE+7)/DDAT(JE+2)/DDAT(JE+6)                          INE30     311
         IF(IDDAT(JE+5).NE.0) THEN                                      INE30     312
            TMAX=TMAX*DDAT(JE+5)                                        INE30     313
            IF (IDDAT(JE+4).NE.0) TMAX=TMAX/(1.0+DDAT(JE+4))            INE30     314
         ENDIF                                                          INE30     315
         IF(IDDAT(JE+9).NE.0) TMAX=TMAX*DDAT(JE+9)/(1.0+DDAT(JE+8))     INE30     316
         IF(IDDAT(JE+3).NE.0) THEN                                      INE30     317
            TMAX=TMAX*DDAT(JE+3)                                        INE30     318
         ENDIF                                                          INE30     319
         IF (TMAX.LT.DTMIN) TMAX=DTMIN                                  INE30     320
      ENDIF                                                             INE30     321
      DDAT(JE+32)=TMAX                                                  INE30     322
C                                                                       INE30     323
      IDDAT(JE+40)=0                                                    INE30     324
      IF(IDDAT(JE+15).NE.0)THEN                                         INE30     325
         IF (EFDN.GT.DDAT(JE+16)) THEN                                  INE30     326
            IDDAT(JE+40)=1                                              INE30     327
            WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)    INE30     328
     *                        ,NDGC(N)                                  INE30     329
            WRITE(MSG(2),9010)                                          INE30     330
            WRITE(MSG(3),9100) EFDN,DDAT(JE+16)                         INE30     331
            CALL PRTMSG(3)                                              INE30     332
         ENDIF                                                          INE30     333
      ENDIF                                                             INE30     334
      IF (EFDN.GT.EFMX.OR.EFDN.LT.EFMN)THEN                             INE30     335
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30     336
     *                     ,NDGC(N)                                     INE30     337
         WRITE(MSG(2),9010)                                             INE30     338
         WRITE(MSG(3),9200)                                             INE30     339
         WRITE(MSG(4),9210) EFDN,EFMX,EFMN                              INE30     340
         CALL PRTMSG(4)                                                 INE30     341
      ENDIF                                                             INE30     342
      IF (VE.GT.DDAT(JE+28).OR.VE.LT.DDAT(JE+29)) THEN                  INE30     343
         WRITE(MSG(1),9000) NLF,INAME(KN-2),INAME(KN-1),INAME(KN)       INE30     344
     *                     ,NDGC(N)                                     INE30     345
         WRITE(MSG(2),9010)                                             INE30     346
         WRITE(MSG(3),9300)                                             INE30     347
         WRITE(MSG(4),9310) VE,DDAT(JE+28),DDAT(JE+29)                  INE30     348
         CALL PRTMSG(4)                                                 INE30     349
      ENDIF                                                             INE30     350
C                                                                       INE30     351
      RETURN                                                            INE30     352
C                                                                       INE30     353
 9000 FORMAT(' *** WARNING GENERATOR AT BUS: ',I5,' STATION: ',3A4      INE30     354
     *,' GID:',A4)                                                      INE30     355
 9010 FORMAT(5X,'TYPE 30 EXCITER (WSCC TYPE FG, FJ OR FK, IEEE TYPE'    INE30     356
     *,' AC4A OR ST1A)')                                                INE30     357
 9020 FORMAT(5X,'ET VIOLATES UPPER LIMIT:  ET = ',G12.5,' ETLMT = '     INE30     358
     *,G12.5)                                                           INE30     359
 9030 FORMAT(5X,A,'=',F8.6,' IS BELOW THE LIMIT VALUE OF',F5.2,:,A      INE30     360
     *,' HAS BEEN SET TO',F5.2)                                         INE30     361
 9050 FORMAT(5X,'TB MUST NOT BE ZERO IF TA IS ZERO AND THE RATE'        INE30     362
     *,' FEEDBACK IS PRESENT.')                                         INE30     363
 9060 FORMAT(5X,'TB IS SET TO',F5.2)                                    INE30     364
 9100 FORMAT(5X,'IFDN VIOLATES UPPER LIMIT:  IFDN = ',G12.5,' IFLMT = ' INE30     365
     *,G12.5)                                                           INE30     366
 9200 FORMAT(5X,'EFDN VIOLATES LIMIT:')                                 INE30     367
 9210 FORMAT(5X,'EFDN = ',G12.5,' EFMX = ',G12.5,' EFMN = ',G12.5)      INE30     368
 9300 FORMAT(5X,'VE VIOLATES LIMITS:')                                  INE30     369
 9310 FORMAT(5X,'VE = ',G12.5,' VIMAX = ',G12.5,' VIMIN = ',G12.5)      INE30     370
C                                                                       INE30     371
      END                                                               INE30     372
