BEGIN { FS = "	" }
   NR == 1 {
    dc = 0
    top = "" prefix ".html"
    f = top
    print top
  }
  /MASTER INDEX/ {
    lastupdate=substr($0, index($0, $2))
    printf("<title>Index of files in the CICA</title>\n")>top
    printf("<h1>Files from CICA Archive</h1>\n")>>top
    printf("<hr><i>These indexes are updated at approximate 7 days intervals. ")>>top
    printf("<p><i>You can use our <a href=search.html>search form</a> if you are looking for a file.</i><hr>")>>top
    printf("<p>%s<p>\n", lastupdate)>>top
    printf("<dl>\n")>>top
    next
  }
  /Index of:/ {
	getline
	title=substr($0,index($0,$2))
	next
  }
  /In Directory:/ {
	dir=substr($0,index($0,root)+length(root)+1)
	olddir=dir
	next
  }
  /On Archive:/ {
	site=$4
	next
  }
  /Last Updated:/ {
	lastupdate=substr($0,index($0,$2))
	next
  }
  /\*\*/ {
        next
  }
  { 
   if (length == 0) next
   if (olddir == dir) {
      dc++ 
      if (dc != 1) printf("</ul>\n")>>f
      close(f)
      n=split(dir,p,"/")
      d=p[1]
      for (i=2; i<=n; i++) d=d "_" p[i]
      f= "" prefix "_" d ".html"
      printf("<dt><b>%s</b>",title) >> top
      printf("<dd><a href=%c%s%c>%s</a><p>\n", 34, f, 34, dir)>>top
      printf("<title>CICA index: %s</title>\n", title)>f
      printf("<h1>%s: <a href=ftp://%s/%s/%s>%s</a></h1>", title, site, root, dir, dir) >> f 
      printf("<hr><i>%s</i><ul>\n", lastupdate)>>f
      print "Creating ",f
      olddir=""
   }
   nw=split($0,word," ")
   comment=substr($0,index($0,word[3]))
   printf("<li><tt><a href=%cftp://%s/%s/%s/%s%c>%-12.12s</a>  %s</tt> %s.\n",34, site, root, dir, word[1], 34, word[1] "____________", word[2], comment)>>f
   }
END {
    printf("</ul>\n")>>f
    printf("</dl>\n")>>top
    printf("<hr><h4>Generated by Ozgur BALSOY. </h4>\n", thisfile)>>top
   }